home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Die Speccy' 97
/
Die Speccy' 97.iso
/
amiga_system
/
the_aminet
/
comm
/
fido
/
js_toss102b.lha
/
js_tosser
/
Install
< prev
next >
Wrap
Text File
|
1995-05-08
|
10KB
|
411 lines
; JS_TOSS Installer Script
; by Jⁿrgen Schmitz
;--------------------------------------------------------------------
;set text vars
;
(set #inst
(cat "Installation script of JS_TOSS.\n\n"
"JS_TOSS is published as SHAREWARE.\n"
"for more details read the manual.\n\n"
"The program is copyright (c) by Jⁿrgen Schmitz\n"
"all rights reserved\n\n"
))
(set #update
(cat "An existing config file of JS_TOSS was found."
))
(set #update_choices_update
(cat "update binaries only"
))
(set #update_choices_new
(cat "install new"
))
(set #start
(cat "Welcome to the installation script of JS_TOSS.\n\n"
"Please read the manual (JS_TOSS.doc) durring and after "
"installation with this script to known what has happened "
"and how to continue.\n\n"
"This script only copies all required data and generates "
"a basic config file. But to use JS_TOSS completely you "
"may need to edit and change the config files by hand to your "
"needs. The doc files will help you!"
))
(set #binaryDrawer
(cat "Select a drawer for the binaries\n"
"(no new directory will be created)"
))
(set #WBbinDrawer
(cat "Select a drawer for the binaries that could be started from "
"Workbench (e.g. the config program).\n"
"(no new directory will be created)"
))
(set #areasDrawer
(cat "Select a drawer for the area config files directory\n"
"(a directory JS_TOSS will be created)"
))
(set #areafixlanguages
(cat "JS_Areafix supports different languages for its reply mails. "
"Now you may choose which one. But you can change this later "
"again to your needs. If the language you want isn't shown "
"here you can simple create it by your own. Look in "
"JS_AREAFIX.doc for details."
))
(set #nodelistDrawer
(cat "Select the drawer of the traplist compiled nodelist"
))
(set #tempDrawer
(cat "Select a drawer for temporary files. This shouldn't be on "
"a ram disk!\n(e.g. make a directory t in mail:)"
))
(set #inboundDrawer
(cat "Select your INBOUND directory"
))
(set #outboundDrawer
(cat "Select your OUTBOUND directory"
))
(set #sysinDrawer
(cat "Select INBOUND directory of SYSOP tosser\n"
"(where your tosser looks for new mail packets)"
))
(set #sysoutDrawer
(cat "Select OUTBOUND directory of SYSOP tosser\n"
"(where your tosser places exported mail packets)"
))
(set #bbsinDrawer
(cat "Select INBOUND directory of your BBS\n"
"(where it looks for new mail packets)"
))
(set #bbsoutDrawer
(cat "Select OUTBOUND directory of your BBS\n"
"(where it places exported mail packets)"
))
(set #node_number
(cat "Enter your FidoNet (or compatibel) address\n"
"(zone:net/node.point)"
))
(set #node_name
(cat "Enter your name (sysop name)\n"
"(allowes AmigaDOS patterns)"
))
(set #node_uplink1
(cat "Enter an uplink address\n"
"(zone:net/node.point)"
))
(set #node_uplink2
(cat "Enter a 2nd up- or downlink address\n"
"(zone:net/node.point)"
))
(set #node_uplink3
(cat "Enter a 3rd up- or downlink address\n"
"(zone:net/node.point)"
))
(set #node_routing
(cat "Enter the general routing address "
"- must be one of your enteres uplinks\n"
"(zone:net/node.point)"
))
(set #node_echo1
(cat "Enter a name of one of your public echos\n"
"(e.g. AMIGA.GER)"
))
(set #node_echo2
(cat "Enter a name of a 2nd one of your public echos\n"
"(e.g. AMIGA.EUR)"
))
(set #wegotit
(cat "We have finished installation! Continue to read the doc file "
"to known what has happened."
))
(set #exit
(cat "JS_TOSS is installed now!\n\nStart JS_TOSS once to generate "
"all required files automatically."
))
(set #exit2
(cat "JS_TOSS updated!\n\nYou may continue to work like before."
))
;--------------------------------------------------------------------
;install
;
(message #inst)
(welcome)
; check if already installed
(if (exists "mail:js_toss.cfg" (noreq))
(
(set upd (askchoice (prompt #update)
(help @askchoice-help)
(choices #update_choices_update
#update_choices_new)))
(if (= 0 upd)
(
(set @default-dest
(askdir (prompt #binaryDrawer)
(default "mail:bin")
(help @askdir-help)))
(copyfiles (source "bin")
(dest @default-dest)
(pattern "#?")
(files)
(infos))
(exit #exit2)
))
))
(message #start)
; ask for dirs
(set @default-dest
(askdir (prompt #binaryDrawer)
(default "mail:bin")
(help @askdir-help)))
(set WBbin
(askdir (prompt #WBbinDrawer)
(default "mail:bin")
(help @askdir-help)))
(set acf_dir
(askdir (prompt #areasDrawer)
(default "mail:")
(help @askdir-help)))
; copy files
(copyfiles (source "bin/JS_Toss")
(dest @default-dest)
(files)
(infos))
(copyfiles (source "bin/JS_CheckAddress")
(dest @default-dest)
(files)
(infos))
(copyfiles (source "bin/JS_Config")
(dest WBbin)
(files)
(infos))
(copyfiles (source "libs")
(dest "libs:")
(pattern "#?")
(files)
(infos))
(set acf_dirname
(tackon acf_dir "js_toss"))
(makedir acf_dirname)
; areafix language
(set lang (askchoice (prompt #areafixlanguages)
(help @askchoice-help)
(choices "deutsch (german)"
"english")))
; german in buildin, so nothing to copy
(if (= 1 lang)
(
(copyfiles (source "Languages/english")
(newname "JS_Areafix.language")
(dest acf_dirname)
(files)
(infos))
))
; generate config file - ask dirs
(set nodelist
(askdir (prompt #nodelistDrawer)
(default "nodelist:")
(help @askdir-help)))
(set tempdir
(askdir (prompt #tempDrawer)
(default "mail:t")
(help @askdir-help)))
(set inb
(askdir (prompt #inboundDrawer)
(default "mail:inbound")
(help @askdir-help)))
(set outb
(askdir (prompt #outboundDrawer)
(default "mail:outbound")
(help @askdir-help)))
(set sysin
(askdir (prompt #sysinDrawer)
(default "mail:sysop_inbound")
(help @askdir-help)))
(set sysout
(askdir (prompt #sysoutDrawer)
(default "mail:sysop_outbound")
(help @askdir-help)))
(set bbsin
(askdir (prompt #bbsinDrawer)
(default "mail:bbs_inbound")
(help @askdir-help)))
(set bbsout
(askdir (prompt #bbsoutDrawer)
(default "mail:bbs_outbound")
(help @askdir-help)))
; ask for some strings
(set node_number
(askstring (prompt #node_number)
(help @askstring-help)))
(set node_name
(askstring (prompt #node_name)
(help @askstring-help)))
(set node_uplink1
(askstring (prompt #node_uplink1)
(help @askstring-help)))
(set node_uplink2
(askstring (prompt #node_uplink2)
(help @askstring-help)))
(set node_uplink3
(askstring (prompt #node_uplink3)
(help @askstring-help)))
(set node_route
(askstring (prompt #node_routing)
(help @askstring-help)
(default node_uplink1)))
(set node_echo1
(askstring (prompt #node_echo1)
(help @askstring-help)))
(set node_echo2
(askstring (prompt #node_echo2)
(help @askstring-help)))
; write config file
(set cfg_file
(cat ";\n"
"; JS_TOSS config\n"
"; also used by JS_AREAFIX\n"
";\n"
"; generated by the installer script\n"
";\n"
"inbound " inb "\n"
"outbound " outb "\n"
"areaconfig " acf_dirname "\n\n"
"bbsin " bbsout "\n"
"bbsout " bbsin "\n\n"
"sysin " sysout "\n"
"sysout " sysin "\n\n"
"; dont forget:\n"
"; JS_TOSS's sysop/bbs inbound is sysop/bbs OUTbound\n"
"; JS_TOSS's sysop/bbs outbound is sysop/bbs INbound\n\n"
"logfile mail:js_toss.log\n"
"tempdir ram:t\n"
";this should be in ram, it's the temp for mail robots\n\n"
"packdir " tempdir "\n"
"; this shouldn't be in ram\n\n"
"secure\nglobalautonew\nbadmail\n"
"nodelist " nodelist "\n\n"
"node " node_number "\n"
" name \"" node_name "\"\n"
" link " node_uplink1 "\n"
" link " node_uplink2 "\n"
" link " node_uplink3 "\n"
" route *:*/*.* " node_route "\n"
" attach *:*/*.*\n"
";file attach allowed for all\n"
" autonew " node_uplink1 "\n"
";only the first link is allowed to make new echos here\n"
"\n;end of node, next node starts with NODE command\n"
"\n\n;\n"
"; JS_Areafix config\n"
";\n"
"packer LHA \"c:lha a\" \"c:lha x\" \"The typical Amiga Packer\"\n"
"packer GZIP \"c:gzip\" \"c:gzip -d\" \"efficient unix packer\"\n"
"\nlogareafix\n"
))
(textfile (dest "mail:js_toss.cfg")
(append cfg_file)
)
; gen zone config file
(set zone "")
(set l (strlen node_number))
(set i 0)
(while (and (<> ":" (substr node_number i 1)) (< i l))
(
(set zone (cat zone (substr node_number i 1)))
(set i (+ i 1))
))
(set zonecfg
(cat "Zone_" zone ".cfg"
))
(set cfg_file
(cat "area \"" node_echo1 "\" \"no description\"\n"
"area \"" node_echo2 "\" \"no description\"\n"
))
(textfile (dest (tackon acf_dirname zonecfg))
(append cfg_file)
)
(message #wegotit)
(exit #exit)